Types de fichiers

Scilab travaille à partir d'un répertoire de base, qui est donné par la commande pwd. C'est là qu'il va chercher par défaut les fichiers à charger ou à exécuter. On peut le changer par la commande chdir. À défaut, il faut saisir le chemin d'accès complet du fichier que l'on souhaite charger ou sauvegarder. Le plus facile est d'utiliser le menu de l'interface $\fbox{Fichier}$ $\longrightarrow$ $\fbox{Changer le r\'epertoire courant}$

Il convient de distinguer trois sortes de fichiers.

Les fichiers de sauvegarde.
Ce sont des fichiers binaires, créés par la commande save et rappelés par load. Ceci permet de reprendre un calcul en conservant les valeurs déjà affectées. On peut aussi enregistrer des variables dans un fichier texte par write et les rappeler par read.
Les fichiers de commandes.
Ce sont des fichiers texte pour lesquels nous recommandons l'extension .sce. Ils contiennent des suites d'instructions Scilab, qui sont exécutées successivement par exec. Enregistrez dans le répertoire courant les trois lignes suivantes sous le nom losange.sce. Attention, la dernière ligne du fichier doit obligatoirement se terminer par un retour-chariot pour être prise en compte.
```
x=[0,-1,0,1;-1,0,1,0]
y=[-1,0,1,0;0,1,0,-1]
plot2d(x,y)
```
La commande exec("losange.sce") affichera x, puis y, puis tracera un losange.
On peut écrire une matrice dans un fichier texte à exécuter (par exemple pour importer des données issues d'un tableur). Dans ce cas, les lignes du fichier, si elles correspondent aux lignes de la matrice, ne doivent pas se terminer par deux points. Par exemple le fichier saisie.sce peut contenir les trois lignes (terminées par un retour-chariot) :
```
A=[1,2,3;
4,5,6;
7,8,9];
```
La commande exec("saisie.sce") affectera la matrice A.
Les fichiers de fonctions. Comme les fichiers de commandes, ce sont des fichiers texte, pour lesquels nous recommandons l'extension standard .sci. Ils contiennent la définition d'une ou plusieurs fonctions. Ces fonctions sont disponibles pour Scilab après les avoir chargées et compilées par exec.
La définition d'une fonction commence obligatoirement par une ligne qui déclare le nom de la fonction, les variables d'entrée x1,...,xm et le vecteur des variables de sortie [y1,...,yn].
```
           function [y1,...,yn] = nom_de_la_fonction(x1,...,xm)
```
${\displaystyle \begin{array}{c} \vdots \ instructions \ \vdots \end{array} }$
```
           endfunction
```
Là encore, il ne faut pas oublier de terminer la dernière ligne par un retour-chariot. Enregistrez par exemple dans le fichier cloche.sci les lignes suivantes.
```
function d = cloche(x)
//
//     densite de la loi normale N(0,1)
//
coef=1/sqrt(2*%pi)
d = coef*exp(-x.^2/2);
endfunction
```
Si ce fichier est placé dans le répertoire courant, exec("cloche.sci") charge et compile la nouvelle fonction.
```
clear
exec("cloche.sci")
t=[-3:0.1:3]; y=cloche(t);
d                         // erreurs : d variable interne
x                         //           x variable interne
coef                      //        coef variable interne
plot2d(t,y)
fplot2d(t,cloche)
intg(-5,1.96,cloche)
```

Il n'y a pas de raison structurelle pour distinguer les fichiers de commande (extension .sce) des fichiers de fonctions (extension .sci). Vous pourriez insérer des définitions de fonctions dans des suites de commandes, mais nous recommandons néanmoins de séparer les fonctions des commandes, de manière à mieux structurer votre programmation et à constituer vos propres librairies de fonctions.

Dès que les calculs à effectuer requièrent plus de quelques lignes de commande, on a intérêt à saisir ces lignes dans un fichier exécutable externe. Dans l'interface de Scilab, les seules commandes qui apparaîtront seront les exécutions ou les chargements répétés de fichiers externes. Il est conseillé de maintenir ouvertes deux fenêtres : la fenêtre Scilab, et une fenêtre d'édition, de préfénce l'éditeur de Scilab : SciNotes accessible par $\fbox{Applications}$ $\longrightarrow$ $\fbox{Scinotes}$ . Les lignes écrites dans Scinotes seront chargées et compilées par le menu $\fbox{Ex\'ecuter}$ de SciNotes, on peut charger (Load) ou évaluer (Evaluate) le contenu. Le menu $\fbox{Fichier}$ $\longrightarrow$ $\fbox{Ex\'ecuter...}$ de la console Scilab permet d'exécuter le contenu d'un fichier sans passer par l'éditeur. Autant pour les fichiers de commande que pour les fichiers de fonctions, une présentation claire et abondamment commentée est vivement recommandée. Pour une utilisation courante ou de mise au point, les fichiers de commandes permettent de suivre le contenu de toutes les variables. Pour une programmation plus avancée, il est préférable de définir des fonctions, car leurs variables internes restent locales. Un même fichier .sci peut contenir plusieurs fonctions. Les fonctions du langage sont regroupées dans des librairies qui contiennent leur code Scilab (fichiers texte .sci), et leur code compilé (fichiers .bin). On peut transformer un ensemble de fichiers de fonctions en librairie, en sauvant les versions compilées et en rajoutant les fichiers d'aide.