function flot = flot1d(mu,sigma,x0,h,n)
//      Retourne une matrice a n+1 lignes et nbtraj colonnes.
//      Les colonnes contiennent des simulations independantes 
//      de trajectoires du processus de diffusion de derive mu 
//      et diffusion sigma (fonctions de deux variables).
//      Les trajectoires sont initialisees par le vecteur x0 et
//      sont simulees par la methode d'Euler de pas h sur n pas.

ntraj=size(x0,"*");                        // nombre de trajectoires
sh = sqrt(h);                              // racine carree du pas
pas_brownien = grand(n,1,"nor",0,sh);      // tirage des pas browniens
flot = zeros(n+1,ntraj);                   // initialisations 
t = 0; X = x0;
flot(1,:) = X;
for i=1:n,                                 // simulation des trajectoires
    X = X + mu(t,X)*h + sigma(t,X)*pas_brownien(i);
    flot(i+1,:) = X;
    t = t+h;
end;
xbasc();



