function moy = GG1(interarrivees,services)
//      Represente en fonction du temps le nombre de clients dans
//      une file d'attente simple. Les vecteurs d'entree (lignes)
//      donnent les durees inter-arrivees et les durees de services.
//      Retourne le nombre moyen de clients dans la file.   

m = min(size(interarrivees,"*"),size(services,"*"));
arr = cumsum(interarrivees(1:m));       // dates d'arrivees
dep = zeros(arr);                       // dates de depart
dep(1) = arr(1) + services(1);          // premier depart
for k=1:m-1,                            // departs suivants
    if dep(k)<arr(k+1) then,
	 dep(k+1) = arr(k+1) + services(k+1);
                       else
	 dep(k+1) = dep(k) + services(k+1);
    end;
end;
arr = [arr;ones(1,m)];                  // +1 pour etiqueter les arrivees
dep = [dep;-ones(1,m)];                 // -1 pour etiqueter les departs
even = [arr,dep];                       // ensemble des evenements
[dates,perm] = gsort(even(1,:),"c","i") // dates triees
nombres = cumsum(even(2,perm))          // nombres de clients
moy = sum(..                            // nombre moyen
          nombres(1:2*m-1).*(dates(2:2*m)-dates(1:2*m-1)))/dates($);
xbasc();
plot2d2("gnn",[0,dates]',[0,nombres]',1,"111",..
          "Nombre de clients",[0,0,max(dates),max(nombres)])






